• mergeRequest.setHeader('Authorization', 'Bearer ' + authToken);

• mergeRequest.setHeader('Content-Type','application/json');

• mergeRequest.setHeader('Accept','application/json');

• Authorization:

  • This header includes the bearer token that was retrieved in getAuth().

  • The format is Bearer <tokenValue>.

  • Without this header, the Conga API will not recognize or authorize the request.

• Content-Type:

  • Set this to application/json to indicate that the body of the request is JSON

  • The Conga Merge endpoint expects a JSON payload describing templates, destinations and merge data.

• Accept:

  • This header indicates what type of response is expected to handle.

  • Setting application/json tells the API a JSON response is expected back.

mergeData.put('templateSources', new List<Map<String, String>>{
    new Map<String, String>{
        'integrationName' => 'conga',
        'fileId'          => fileId
    }
});

• integrationName - Typically set to 'conga' when using Conga Drive as the integration.

• fileID - this is the ID of the template stored in Conga Drive. This was defined earlier as: private string final String fileId= 'bd533afe-173b-4347-90eb-56f9f2b55db4'; This is wrapped in a List<Map<String, String>> because the API supports multiple templates. In this example it is only one.

mergeData.put('destinations', new List<Map<String, String>>{
    new Map<String, String>{
        'integrationName' => 'conga',
        'folderId'        => 'root'
    }
});

• integrationName - Set to 'conga', indicating Conga Drive as the integration destination.

• folderId - 'root' indicates the final merged document will be stored in the root folder. If using a specific folder id, replace 'root' with the appropriate folder ID. Just like templateSources, ths can be multiple values to indicate multiple destinations.

mergeData.put('jsondata', JSON.serialize(new Map<String, String>{
    'firstname' => 'SampleData',
    'lastname'  => 'SampleData'
}));

• firstname→"SampleData"
• lastname→"SampleData"
• The keys ('firstname','lastname') should match the merge fields defined in your Conga template.
• The JSON.serialize(...) calls that serialized JSON string into the jsondata key of our outer mergeData map.
  Important: JSONdata itself is expected as a string in the top-level JSON.
• You must serialize the inner map first, rather than embedding it directly as a nested JSON object.
• You can expand this map with as many merge fields as you need—simply add more key-value pairs that match your template fields.

• Status or result of the merge.
• Information about the generated document (location, ID, etc.), depending on the specific API contract.
• Additional checks can be added here, similar to the auth method:

• Check response.getStatusCode() for 2xx to confirm success.

• Log or handle errors if you receive a 4xx or 5xx code.

private static void startMerge() {
    System.debug('Merge process has begun...');
    // Create our HTTP request for the Merge API
    HttpRequest mergeRequest = new HttpRequest();
    // Set the endpoint for the merge call
    mergeRequest.setEndpoint(mergeUrl);
    // Use POST since we are sending a JSON body
    mergeRequest.setMethod('POST');
    // Add the Bearer token and JSON headers
    mergeRequest.setHeader('Authorization', 'Bearer ' + authToken);
    mergeRequest.setHeader('Content-Type', 'application/json');
    mergeRequest.setHeader('Accept', 'application/json');
    // Build the JSON payload
    Map<String, Object> mergeData = new Map<String, Object>();
    // Legacy options (such as output file name)
    mergeData.put('LegacyOptions', new Map<String, String>{
        'OFN' => 'mergingFromCongaDrive'
    });
    // Template source - which template to merge against
    mergeData.put('templateSources', new List<Map<String, String>>{
        new Map<String, String>{
            'integrationName' => 'conga',
            'fileId'          => fileId
        }
    });
    // Destination - where the merged file should be stored
    mergeData.put('destinations', new List<Map<String, String>>{
        new Map<String, String>{
            'integrationName' => 'conga',
            'folderId'        => 'root'
        }
    });
    // Merge field data for the template
    mergeData.put('jsondata', JSON.serialize(new Map<String, String>{
        'firstname' => 'SampleData',
        'lastname'  => 'SampleData'
    }));
    // Serialize the entire payload and set it as the request body
    mergeRequest.setBody(JSON.serialize(mergeData));
    // Send the request and capture the response
    HttpResponse response = new Http().send(mergeRequest);
    // Log the full response for verification and troubleshooting
    System.debug('Merge Response Status Code: ' + response.getStatusCode());
    System.debug('Merge Response Body: ' + response.getBody());
}